LOTUSSCRIPT/COM/OLE CLASSES
Examples: CreateChildEntity method
1. This agent creates a multipart MIME entity suitable for a mail memo. The parent entity contains headers that define a Domino mail memo. Two child entities contain the content of the memo.
Sub Initialize
Dim s As New NotesSession
Dim db As NotesDatabase
Dim doc As NotesDocument
Dim body As NotesMIMEEntity
Dim header As NotesMIMEHeader
Dim child As NotesMIMEEntity
Dim stream As NotesStream
Set db = s.CurrentDatabase
Set stream = s.CreateStream
s.ConvertMIME = False
Set doc = db.CreateDocument
REM Create the parent entity
Call doc.ReplaceItemValue("Form", "Memo")
Set body = doc.CreateMIMEEntity
REM Create header for Content-Type
Set header = body.CreateHeader("Content-Type")
Call header.SetHeaderVal("multipart/mixed")
REM Create additional headers for mail message
Set header = body.CreateHeader("Subject")
Call header.SetHeaderVal("MIME multipart message")
Set header = body.CreateHeader("To")
Call header.SetHeaderVal("Roberta Person")
REM Create child entity
Set child = body.CreateChildEntity
Call stream.WriteText("Text of message for child 1." & _
Chr(10) & Chr(10))
Call child.SetContentFromText(stream, _
"text/plain", ENC_NONE)
Call stream.Truncate
REM Create another child entity
Call stream.WriteText("Text of message for child 2.")
Set child = body.CreateChildEntity
Call child.SetContentFromText(stream, _
"text/plain", ENC_NONE)
Call doc.Send(False)
s.ConvertMIME = True ' Restore conversion
End Sub
2. This agent creates a multipart MIME entity with two child entities. The child entities are positioned in reverse order.
Sub Initialize
Dim s As New NotesSession
Dim db As NotesDatabase
Dim doc As NotesDocument
Dim body As NotesMIMEEntity
Dim header As NotesMIMEHeader
Dim child As NotesMIMEEntity
Dim stream As NotesStream
Set db = s.CurrentDatabase
Set stream = s.CreateStream
s.ConvertMIME = False
Set doc = db.CreateDocument
REM Create the parent entity
Call doc.ReplaceItemValue("Form", "Main Form")
Set body = doc.CreateMIMEEntity
REM Create header for Content-Type
Set header = body.CreateHeader("Content-Type")
Call header.SetHeaderVal("multipart/mixed")
REM Create additional headers for mail message
Set header = body.CreateHeader("Subject")
Call header.SetHeaderVal("MIME multipart message")
REM Create child entity
Set child = body.CreateChildEntity
Call stream.WriteText("Text of message for child 1.")
Call child.SetContentFromText(stream, _
"text/plain", ENC_NONE)
Call stream.Truncate
REM Create another child entity
Call stream.WriteText("Text of message for child 2." & _
Chr(10) & Chr(10))
Set child = body.CreateChildEntity(child)
Call child.SetContentFromText(stream, _
"text/plain", ENC_NONE)
Call doc.Save(True, True)
s.ConvertMIME = True ' Restore conversion
End Sub
See Also
CreateChildEntity method
Glossary
Feedback on
Help
or
Product Usability
?
Help on Help
All Help Contents
Glossary