LOTUSSCRIPT/COM/OLE CLASSES

Examples: CreateHeader method
This agent creates Content-Type, Subject, and To headers for the parent entity in a multipart MIME entity. SetContentFromText generates headers for the child entities through parameters 2 (Content-Type) and 3 (Content-Transfer-Encoding).

Sub Initialize
 Dim s As New NotesSession
 Dim db As NotesDatabase
 Dim doc As NotesDocument
 Dim body As NotesMIMEEntity
 Dim header As NotesMIMEHeader
 Dim child As NotesMIMEEntity
 Dim stream As NotesStream
 Set db = s.CurrentDatabase
 s.ConvertMIME = False ' Retain MIME format
 Set doc = db.CreateDocument
REM Create parent entity
 Call doc.ReplaceItemValue("Form", "Memo")
 Set body = doc.CreateMIMEEntity
 Set header = body.CreateHeader("Content-Type")
 Call header.SetHeaderVal("multipart/mixed")
 Set header = body.CreateHeader("Subject")
 Call header.SetHeaderVal("MIME multipart message")
 Set header = body.CreateHeader("To")
 Call header.SetHeaderVal("Roberta Person")
 Set stream = s.CreateStream
REM Create first child entity
 Set child = body.CreateChildEntity
 Call stream.WriteText("Text of message for child 1." _
 & Chr(10) & Chr(10))
 Call child.SetContentFromText(stream, "text/plain", _
 ENC_QUOTED_PRINTABLE)
 Call stream.Truncate
REM Create second child entity
 Set child = body.CreateChildEntity
 Call stream.WriteText("Text of message for child 2.")
 Call child.SetContentFromText(stream, "text/plain", _
 ENC_QUOTED_PRINTABLE)
 Call doc.Save(True, True)
 s.ConvertMIME = True ' Restore conversion
End Sub

See Also